home *** CD-ROM | disk | FTP | other *** search
/ SGI Freeware 1999 August / SGI Freeware 1999 August.iso / dist / fw_xemacs.idb / usr / freeware / lib / xemacs-20.4 / lisp / gnus / nnfolder.el.z / nnfolder.el
Encoding:
Text File  |  1998-05-21  |  27.6 KB  |  785 lines
  1. ;;; nnfolder.el --- mail folder access for Gnus
  2. ;; Copyright (C) 1995,96,97 Free Software Foundation, Inc.
  3.  
  4. ;; Author: Scott Byer <byer@mv.us.adobe.com>
  5. ;;    Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
  6. ;;     Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
  7. ;; Keywords: mail
  8.  
  9. ;; This file is part of GNU Emacs.
  10.  
  11. ;; GNU Emacs is free software; you can redistribute it and/or modify
  12. ;; it under the terms of the GNU General Public License as published by
  13. ;; the Free Software Foundation; either version 2, or (at your option)
  14. ;; any later version.
  15.  
  16. ;; GNU Emacs is distributed in the hope that it will be useful,
  17. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19. ;; GNU General Public License for more details.
  20.  
  21. ;; You should have received a copy of the GNU General Public License
  22. ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23. ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24. ;; Boston, MA 02111-1307, USA.
  25.  
  26. ;;; Commentary:
  27.  
  28. ;;; Code:
  29.  
  30. (require 'nnheader)
  31. (require 'message)
  32. (require 'nnmail)
  33. (require 'nnoo)
  34. (require 'cl)
  35. (require 'gnus-util)
  36.  
  37. (nnoo-declare nnfolder)
  38.  
  39. (defvoo nnfolder-directory (expand-file-name message-directory)
  40.   "The name of the nnfolder directory.")
  41.  
  42. (defvoo nnfolder-active-file
  43.   (nnheader-concat nnfolder-directory "active")
  44.   "The name of the active file.")
  45.  
  46. ;; I renamed this variable to something more in keeping with the general GNU
  47. ;; style. -SLB
  48.  
  49. (defvoo nnfolder-ignore-active-file nil
  50.   "If non-nil, causes nnfolder to do some extra work in order to determine
  51. the true active ranges of an mbox file.  Note that the active file is still
  52. saved, but it's values are not used.  This costs some extra time when
  53. scanning an mbox when opening it.")
  54.  
  55. (defvoo nnfolder-distrust-mbox nil
  56.   "If non-nil, causes nnfolder to not trust the user with respect to
  57. inserting unaccounted for mail in the middle of an mbox file.  This can greatly
  58. slow down scans, which now must scan the entire file for unmarked messages.
  59. When nil, scans occur forward from the last marked message, a huge
  60. time saver for large mailboxes.")
  61.  
  62. (defvoo nnfolder-newsgroups-file
  63.   (concat (file-name-as-directory nnfolder-directory) "newsgroups")
  64.   "Mail newsgroups description file.")
  65.  
  66. (defvoo nnfolder-get-new-mail t
  67.   "If non-nil, nnfolder will check the incoming mail file and split the mail.")
  68.  
  69. (defvoo nnfolder-prepare-save-mail-hook nil
  70.   "Hook run narrowed to an article before saving.")
  71.  
  72. (defvoo nnfolder-save-buffer-hook nil
  73.   "Hook run before saving the nnfolder mbox buffer.")
  74.  
  75. (defvoo nnfolder-inhibit-expiry nil
  76.   "If non-nil, inhibit expiry.")
  77.  
  78.  
  79.  
  80. (defconst nnfolder-version "nnfolder 1.0"
  81.   "nnfolder version.")
  82.  
  83. (defconst nnfolder-article-marker "X-Gnus-Article-Number: "
  84.   "String used to demarcate what the article number for a message is.")
  85.  
  86. (defvoo nnfolder-current-group nil)
  87. (defvoo nnfolder-current-buffer nil)
  88. (defvoo nnfolder-status-string "")
  89. (defvoo nnfolder-group-alist nil)
  90. (defvoo nnfolder-buffer-alist nil)
  91. (defvoo nnfolder-scantime-alist nil)
  92. (defvoo nnfolder-active-timestamp nil)
  93.  
  94.  
  95.  
  96. ;;; Interface functions
  97.  
  98. (nnoo-define-basics nnfolder)
  99.  
  100. (deffoo nnfolder-retrieve-headers (articles &optional group server fetch-old)
  101.   (save-excursion
  102.     (set-buffer nntp-server-buffer)
  103.     (erase-buffer)
  104.     (let (article art-string start stop)
  105.       (nnfolder-possibly-change-group group server)
  106.       (when nnfolder-current-buffer
  107.     (set-buffer nnfolder-current-buffer)
  108.     (goto-char (point-min))
  109.     (if (stringp (car articles))
  110.         'headers
  111.       (while articles
  112.         (setq article (car articles))
  113.         (setq art-string (nnfolder-article-string article))
  114.         (set-buffer nnfolder-current-buffer)
  115.         (when (or (search-forward art-string nil t)
  116.               ;; Don't search the whole file twice!  Also, articles
  117.               ;; probably have some locality by number, so searching
  118.               ;; backwards will be faster.  Especially if we're at the
  119.               ;; beginning of the buffer :-). -SLB
  120.               (search-backward art-string nil t))
  121.           (nnmail-search-unix-mail-delim-backward)
  122.           (setq start (point))
  123.           (search-forward "\n\n" nil t)
  124.           (setq stop (1- (point)))
  125.           (set-buffer nntp-server-buffer)
  126.           (insert (format "221 %d Article retrieved.\n" article))
  127.           (insert-buffer-substring nnfolder-current-buffer start stop)
  128.           (goto-char (point-max))
  129.           (insert ".\n"))
  130.         (setq articles (cdr articles)))
  131.  
  132.       (set-buffer nntp-server-buffer)
  133.       (nnheader-fold-continuation-lines)
  134.       'headers)))))
  135.  
  136. (deffoo nnfolder-open-server (server &optional defs)
  137.   (nnoo-change-server 'nnfolder server defs)
  138.   (nnmail-activate 'nnfolder t)
  139.   (gnus-make-directory nnfolder-directory)
  140.   (cond
  141.    ((not (file-exists-p nnfolder-directory))
  142.     (nnfolder-close-server)
  143.     (nnheader-report 'nnfolder "Couldn't create directory: %s"
  144.              nnfolder-directory))
  145.    ((not (file-directory-p (file-truename nnfolder-directory)))
  146.     (nnfolder-close-server)
  147.     (nnheader-report 'nnfolder "Not a directory: %s" nnfolder-directory))
  148.    (t
  149.     (nnmail-activate 'nnfolder)
  150.     (nnheader-report 'nnfolder "Opened server %s using directory %s"
  151.              server nnfolder-directory)
  152.     t)))
  153.  
  154. (deffoo nnfolder-request-close ()
  155.   (let ((alist nnfolder-buffer-alist))
  156.     (while alist
  157.       (nnfolder-close-group (caar alist) nil t)
  158.       (setq alist (cdr alist))))
  159.   (nnoo-close-server 'nnfolder)
  160.   (setq nnfolder-buffer-alist nil
  161.     nnfolder-group-alist nil))
  162.  
  163. (deffoo nnfolder-request-article (article &optional group server buffer)
  164.   (nnfolder-possibly-change-group group server)
  165.   (save-excursion
  166.     (set-buffer nnfolder-current-buffer)
  167.     (goto-char (point-min))
  168.     (when (search-forward (nnfolder-article-string article) nil t)
  169.       (let (start stop)
  170.     (nnmail-search-unix-mail-delim-backward)
  171.     (setq start (point))
  172.     (forward-line 1)
  173.     (unless (and (nnmail-search-unix-mail-delim)
  174.              (forward-line -1))
  175.       (goto-char (point-max)))
  176.     (setq stop (point))
  177.     (let ((nntp-server-buffer (or buffer nntp-server-buffer)))
  178.       (set-buffer nntp-server-buffer)
  179.       (erase-buffer)
  180.       (insert-buffer-substring nnfolder-current-buffer start stop)
  181.       (goto-char (point-min))
  182.       (while (looking-at "From ")
  183.         (delete-char 5)
  184.         (insert "X-From-Line: ")
  185.         (forward-line 1))
  186.       (if (numberp article)
  187.           (cons nnfolder-current-group article)
  188.         (goto-char (point-min))
  189.         (search-forward (concat "\n" nnfolder-article-marker))
  190.         (cons nnfolder-current-group
  191.           (string-to-int
  192.            (buffer-substring
  193.             (point) (progn (end-of-line) (point)))))))))))
  194.  
  195. (deffoo nnfolder-request-group (group &optional server dont-check)
  196.   (nnfolder-possibly-change-group group server t)
  197.   (save-excursion
  198.     (if (not (assoc group nnfolder-group-alist))
  199.     (nnheader-report 'nnfolder "No such group: %s" group)
  200.       (if dont-check
  201.       (progn
  202.         (nnheader-report 'nnfolder "Selected group %s" group)
  203.         t)
  204.     (let* ((active (assoc group nnfolder-group-alist))
  205.            (group (car active))
  206.            (range (cadr active)))
  207.       (cond
  208.        ((null active)
  209.         (nnheader-report 'nnfolder "No such group: %s" group))
  210.        ((null nnfolder-current-group)
  211.         (nnheader-report 'nnfolder "Empty group: %s" group))
  212.        (t
  213.         (nnheader-report 'nnfolder "Selected group %s" group)
  214.         (nnheader-insert "211 %d %d %d %s\n"
  215.                  (1+ (- (cdr range) (car range)))
  216.                  (car range) (cdr range) group))))))))
  217.  
  218. (deffoo nnfolder-request-scan (&optional group server)
  219.   (nnfolder-possibly-change-group nil server)
  220.   (when nnfolder-get-new-mail
  221.     (nnfolder-possibly-change-group group server)
  222.     (nnmail-get-new-mail
  223.      'nnfolder
  224.      (lambda ()
  225.        (let ((bufs nnfolder-buffer-alist))
  226.      (save-excursion
  227.        (while bufs
  228.          (if (not (gnus-buffer-live-p (nth 1 (car bufs))))
  229.          (setq nnfolder-buffer-alist
  230.                (delq (car bufs) nnfolder-buffer-alist))
  231.            (set-buffer (nth 1 (car bufs)))
  232.            (nnfolder-save-buffer)
  233.            (kill-buffer (current-buffer)))
  234.          (setq bufs (cdr bufs))))))
  235.      nnfolder-directory
  236.      group)))
  237.  
  238. ;; Don't close the buffer if we're not shutting down the server.  This way,
  239. ;; we can keep the buffer in the group buffer cache, and not have to grovel
  240. ;; over the buffer again unless we add new mail to it or modify it in some
  241. ;; way.
  242.  
  243. (deffoo nnfolder-close-group (group &optional server force)
  244.   ;; Make sure we _had_ the group open.
  245.   (when (or (assoc group nnfolder-buffer-alist)
  246.         (equal group nnfolder-current-group))
  247.     (let ((inf (assoc group nnfolder-buffer-alist)))
  248.       (when inf
  249.     (when (and nnfolder-current-group
  250.            nnfolder-current-buffer)
  251.       (push (list nnfolder-current-group nnfolder-current-buffer)
  252.         nnfolder-buffer-alist))
  253.     (setq nnfolder-buffer-alist
  254.           (delq inf nnfolder-buffer-alist))
  255.     (setq nnfolder-current-buffer (cadr inf)
  256.           nnfolder-current-group (car inf))))
  257.     (when (and nnfolder-current-buffer
  258.            (buffer-name nnfolder-current-buffer))
  259.       (save-excursion
  260.     (set-buffer nnfolder-current-buffer)
  261.     ;; If the buffer was modified, write the file out now.
  262.     (nnfolder-save-buffer)
  263.     ;; If we're shutting the server down, we need to kill the
  264.     ;; buffer and remove it from the open buffer list.  Or, of
  265.     ;; course, if we're trying to minimize our space impact.
  266.     (kill-buffer (current-buffer))
  267.     (setq nnfolder-buffer-alist (delq (assoc group nnfolder-buffer-alist)
  268.                       nnfolder-buffer-alist)))))
  269.   (setq nnfolder-current-group nil
  270.     nnfolder-current-buffer nil)
  271.   t)
  272.  
  273. (deffoo nnfolder-request-create-group (group &optional server args)
  274.   (nnfolder-possibly-change-group nil server)
  275.   (nnmail-activate 'nnfolder)
  276.   (when group
  277.     (unless (assoc group nnfolder-group-alist)
  278.       (push (list group (cons 1 0)) nnfolder-group-alist)
  279.       (nnmail-save-active nnfolder-group-alist nnfolder-active-file)
  280.       (nnfolder-read-folder group)))
  281.   t)
  282.  
  283. (deffoo nnfolder-request-list (&optional server)
  284.   (nnfolder-possibly-change-group nil server)
  285.   (save-excursion
  286.     ;; 1997/8/14 by MORIOKA Tomohiko
  287.     ;;    for XEmacs/mule.
  288.     (let ((nnmail-file-coding-system nnmail-active-file-coding-system)
  289.       (pathname-coding-system 'binary)) ; for XEmacs/mule
  290.       (nnmail-find-file nnfolder-active-file)
  291.       (setq nnfolder-group-alist (nnmail-get-active)))
  292.     t))
  293.  
  294. (deffoo nnfolder-request-newgroups (date &optional server)
  295.   (nnfolder-possibly-change-group nil server)
  296.   (nnfolder-request-list server))
  297.  
  298. (deffoo nnfolder-request-list-newsgroups (&optional server)
  299.   (nnfolder-possibly-change-group nil server)
  300.   (save-excursion
  301.     (nnmail-find-file nnfolder-newsgroups-file)))
  302.  
  303. (deffoo nnfolder-request-expire-articles
  304.   (articles newsgroup &optional server force)
  305.   (nnfolder-possibly-change-group newsgroup server)
  306.   (let* ((is-old t)
  307.      rest)
  308.     (nnmail-activate 'nnfolder)
  309.  
  310.     (save-excursion
  311.       (set-buffer nnfolder-current-buffer)
  312.       (while (and articles is-old)
  313.     (goto-char (point-min))
  314.     (when (search-forward (nnfolder-article-string (car articles)) nil t)
  315.       (if (setq is-old
  316.             (nnmail-expired-article-p
  317.              newsgroup
  318.              (buffer-substring
  319.               (point) (progn (end-of-line) (point)))
  320.              force nnfolder-inhibit-expiry))
  321.           (progn
  322.         (nnheader-message 5 "Deleting article %d..."
  323.                   (car articles) newsgroup)
  324.         (nnfolder-delete-mail))
  325.         (push (car articles) rest)))
  326.     (setq articles (cdr articles)))
  327.       (unless nnfolder-inhibit-expiry
  328.     (nnheader-message 5 "Deleting articles...done"))
  329.       (nnfolder-save-buffer)
  330.       (nnfolder-adjust-min-active newsgroup)
  331.       (nnmail-save-active nnfolder-group-alist nnfolder-active-file)
  332.       (nconc rest articles))))
  333.  
  334. (deffoo nnfolder-request-move-article
  335.   (article group server accept-form &optional last)
  336.   (let ((buf (get-buffer-create " *nnfolder move*"))
  337.     result)
  338.     (and
  339.      (nnfolder-request-article article group server)
  340.      (save-excursion
  341.        (set-buffer buf)
  342.        (buffer-disable-undo (current-buffer))
  343.        (erase-buffer)
  344.        (insert-buffer-substring nntp-server-buffer)
  345.        (goto-char (point-min))
  346.        (while (re-search-forward
  347.            (concat "^" nnfolder-article-marker)
  348.            (save-excursion (search-forward "\n\n" nil t) (point)) t)
  349.      (delete-region (progn (beginning-of-line) (point))
  350.             (progn (forward-line 1) (point))))
  351.        (setq result (eval accept-form))
  352.        (kill-buffer buf)
  353.        result)
  354.      (save-excursion
  355.        (nnfolder-possibly-change-group group server)
  356.        (set-buffer nnfolder-current-buffer)
  357.        (goto-char (point-min))
  358.        (when (search-forward (nnfolder-article-string article) nil t)
  359.      (nnfolder-delete-mail))
  360.        (when last
  361.      (nnfolder-save-buffer)
  362.      (nnfolder-adjust-min-active group)
  363.      (nnmail-save-active nnfolder-group-alist nnfolder-active-file))))
  364.     result))
  365.  
  366. (deffoo nnfolder-request-accept-article (group &optional server last)
  367.   (nnfolder-possibly-change-group group server)
  368.   (nnmail-check-syntax)
  369.   (let ((buf (current-buffer))
  370.     result art-group)
  371.     (goto-char (point-min))
  372.     (when (looking-at "X-From-Line: ")
  373.       (replace-match "From "))
  374.     (and
  375.      (nnfolder-request-list)
  376.      (save-excursion
  377.        (set-buffer buf)
  378.        (goto-char (point-min))
  379.        (search-forward "\n\n" nil t)
  380.        (forward-line -1)
  381.        (while (re-search-backward (concat "^" nnfolder-article-marker) nil t)
  382.      (delete-region (point) (progn (forward-line 1) (point))))
  383.        (when nnmail-cache-accepted-message-ids
  384.      (nnmail-cache-insert (nnmail-fetch-field "message-id")))
  385.        (setq result (if (stringp group)
  386.             (list (cons group (nnfolder-active-number group)))
  387.               (setq art-group
  388.                 (nnmail-article-group 'nnfolder-active-number))))
  389.        (if (and (null result)
  390.         (yes-or-no-p "Moved to `junk' group; delete article? "))
  391.        (setq result 'junk)
  392.      (setq result
  393.            (car (nnfolder-save-mail result)))))
  394.      (when last
  395.        (save-excursion
  396.      (nnfolder-possibly-change-folder (or (caar art-group) group))
  397.      (nnfolder-save-buffer)
  398.      (when nnmail-cache-accepted-message-ids
  399.        (nnmail-cache-close)))))
  400.     (nnmail-save-active nnfolder-group-alist nnfolder-active-file)
  401.     (unless result
  402.       (nnheader-report 'nnfolder "Couldn't store article"))
  403.     result))
  404.  
  405. (deffoo nnfolder-request-replace-article (article group buffer)
  406.   (nnfolder-possibly-change-group group)
  407.   (save-excursion
  408.     (set-buffer nnfolder-current-buffer)
  409.     (goto-char (point-min))
  410.     (if (not (search-forward (nnfolder-article-string article) nil t))
  411.     nil
  412.       (nnfolder-delete-mail t t)
  413.       (insert-buffer-substring buffer)
  414.       (nnfolder-save-buffer)
  415.       t)))
  416.  
  417. (deffoo nnfolder-request-delete-group (group &optional force server)
  418.   (nnfolder-close-group group server t)
  419.   ;; Delete all articles in GROUP.
  420.   (if (not force)
  421.       ()                ; Don't delete the articles.
  422.     ;; Delete the file that holds the group.
  423.     (ignore-errors
  424.       (delete-file (nnfolder-group-pathname group))))
  425.   ;; Remove the group from all structures.
  426.   (setq nnfolder-group-alist
  427.     (delq (assoc group nnfolder-group-alist) nnfolder-group-alist)
  428.     nnfolder-current-group nil
  429.     nnfolder-current-buffer nil)
  430.   ;; Save the active file.
  431.   (nnmail-save-active nnfolder-group-alist nnfolder-active-file)
  432.   t)
  433.  
  434. (deffoo nnfolder-request-rename-group (group new-name &optional server)
  435.   (nnfolder-possibly-change-group group server)
  436.   (save-excursion
  437.     (set-buffer nnfolder-current-buffer)
  438.     (and (file-writable-p buffer-file-name)
  439.      (ignore-errors
  440.        (rename-file
  441.         buffer-file-name
  442.         (nnfolder-group-pathname new-name))
  443.        t)
  444.      ;; That went ok, so we change the internal structures.
  445.      (let ((entry (assoc group nnfolder-group-alist)))
  446.        (and entry (setcar entry new-name))
  447.        (setq nnfolder-current-buffer nil
  448.          nnfolder-current-group nil)
  449.        ;; Save the new group alist.
  450.        (nnmail-save-active nnfolder-group-alist nnfolder-active-file)
  451.        ;; We kill the buffer instead of renaming it and stuff.
  452.        (kill-buffer (current-buffer))
  453.        t))))
  454.  
  455. (defun nnfolder-request-regenerate (server)
  456.   (nnfolder-possibly-change-group nil server)
  457.   (nnfolder-generate-active-file)
  458.   t)
  459.  
  460.  
  461. ;;; Internal functions.
  462.  
  463. (defun nnfolder-adjust-min-active (group)
  464.   ;; Find the lowest active article in this group.
  465.   (let* ((active (cadr (assoc group nnfolder-group-alist)))
  466.      (marker (concat "\n" nnfolder-article-marker))
  467.      (number "[0-9]+")
  468.      (activemin (cdr active)))
  469.     (save-excursion
  470.       (set-buffer nnfolder-current-buffer)
  471.       (goto-char (point-min))
  472.       (while (and (search-forward marker nil t)
  473.           (re-search-forward number nil t))
  474.     (setq activemin (min activemin
  475.                  (string-to-number (buffer-substring
  476.                         (match-beginning 0)
  477.                         (match-end 0))))))
  478.       (setcar active activemin))))
  479.  
  480. (defun nnfolder-article-string (article)
  481.   (if (numberp article)
  482.       (concat "\n" nnfolder-article-marker (int-to-string article) " ")
  483.     (concat "\nMessage-ID: " article)))
  484.  
  485. (defun nnfolder-delete-mail (&optional force leave-delim)
  486.   "Delete the message that point is in."
  487.   (save-excursion
  488.     (delete-region
  489.      (save-excursion
  490.        (nnmail-search-unix-mail-delim-backward)
  491.        (if leave-delim (progn (forward-line 1) (point))
  492.      (point)))
  493.      (progn
  494.        (forward-line 1)
  495.        (if (nnmail-search-unix-mail-delim)
  496.        (if (and (not (bobp)) leave-delim)
  497.            (progn (forward-line -2) (point))
  498.          (point))
  499.      (point-max))))))
  500.  
  501. (defun nnfolder-possibly-change-group (group &optional server dont-check)
  502.   ;; Change servers.
  503.   (when (and server
  504.          (not (nnfolder-server-opened server)))
  505.     (nnfolder-open-server server))
  506.   (unless (gnus-buffer-live-p nnfolder-current-buffer)
  507.     (setq nnfolder-current-buffer nil
  508.       nnfolder-current-group nil))
  509.   ;; Change group.
  510.   (when (and group
  511.          (not (equal group nnfolder-current-group)))
  512.     (let ((pathname-coding-system 'binary))
  513.       (nnmail-activate 'nnfolder)
  514.       (when (and (not (assoc group nnfolder-group-alist))
  515.          (not (file-exists-p
  516.                (nnfolder-group-pathname group))))
  517.     ;; The group doesn't exist, so we create a new entry for it.
  518.     (push (list group (cons 1 0)) nnfolder-group-alist)
  519.     (nnmail-save-active nnfolder-group-alist nnfolder-active-file))
  520.  
  521.       (if dont-check
  522.       (setq nnfolder-current-group group
  523.         nnfolder-current-buffer nil)
  524.     (let (inf file)
  525.       ;; If we have to change groups, see if we don't already have the
  526.       ;; folder in memory.  If we do, verify the modtime and destroy
  527.       ;; the folder if needed so we can rescan it.
  528.       (setq nnfolder-current-buffer
  529.         (nth 1 (assoc group nnfolder-buffer-alist)))
  530.  
  531.       ;; If the buffer is not live, make sure it isn't in the alist.  If it
  532.       ;; is live, verify that nobody else has touched the file since last
  533.       ;; time.
  534.       (when (and nnfolder-current-buffer
  535.              (not (gnus-buffer-live-p nnfolder-current-buffer)))
  536.         (setq nnfolder-buffer-alist (delq inf nnfolder-buffer-alist)
  537.           nnfolder-current-buffer nil))
  538.  
  539.       (setq nnfolder-current-group group)
  540.  
  541.       (when (or (not nnfolder-current-buffer)
  542.             (not (verify-visited-file-modtime nnfolder-current-buffer)))
  543.         (save-excursion
  544.           (setq file (nnfolder-group-pathname group))
  545.           ;; See whether we need to create the new file.
  546.           (unless (file-exists-p file)
  547.         (gnus-make-directory (file-name-directory file))
  548.         (nnmail-write-region 1 1 file t 'nomesg))
  549.           (when (setq nnfolder-current-buffer (nnfolder-read-folder group))
  550.         (set-buffer nnfolder-current-buffer)
  551.         (push (list group nnfolder-current-buffer)
  552.               nnfolder-buffer-alist)))))))))
  553.  
  554. (defun nnfolder-save-mail (group-art-list)
  555.   "Called narrowed to an article."
  556.   (let* (save-list group-art)
  557.     (goto-char (point-min))
  558.     ;; The From line may have been quoted by movemail.
  559.     (when (looking-at (concat ">" message-unix-mail-delimiter))
  560.       (delete-char 1))
  561.     ;; This might come from somewhere else.
  562.     (unless (looking-at message-unix-mail-delimiter)
  563.       (insert "From nobody " (current-time-string) "\n")
  564.       (goto-char (point-min)))
  565.     ;; Quote all "From " lines in the article.
  566.     (forward-line 1)
  567.     (let (case-fold-search)
  568.       (while (re-search-forward "^From " nil t)
  569.     (beginning-of-line)
  570.     (insert "> ")))
  571.     (setq save-list group-art-list)
  572.     (nnmail-insert-lines)
  573.     (nnmail-insert-xref group-art-list)
  574.     (run-hooks 'nnmail-prepare-save-mail-hook)
  575.     (run-hooks 'nnfolder-prepare-save-mail-hook)
  576.  
  577.     ;; Insert the mail into each of the destination groups.
  578.     (while (setq group-art (pop group-art-list))
  579.       ;; Kill any previous newsgroup markers.
  580.       (goto-char (point-min))
  581.       (search-forward "\n\n" nil t)
  582.       (forward-line -1)
  583.       (while (search-backward (concat "\n" nnfolder-article-marker) nil t)
  584.     (delete-region (1+ (point)) (progn (forward-line 2) (point))))
  585.  
  586.       ;; Insert the new newsgroup marker.
  587.       (nnfolder-insert-newsgroup-line group-art)
  588.  
  589.       (save-excursion
  590.     (let ((beg (point-min))
  591.           (end (point-max))
  592.           (obuf (current-buffer)))
  593.       (nnfolder-possibly-change-folder (car group-art))
  594.       (let ((buffer-read-only nil))
  595.         (goto-char (point-max))
  596.         (unless (eolp)
  597.           (insert "\n"))
  598.         (unless (bobp)
  599.           (insert "\n"))
  600.         (insert-buffer-substring obuf beg end)))))
  601.  
  602.     ;; Did we save it anywhere?
  603.     save-list))
  604.  
  605. (defun nnfolder-insert-newsgroup-line (group-art)
  606.   (save-excursion
  607.     (goto-char (point-min))
  608.     (when (search-forward "\n\n" nil t)
  609.       (forward-char -1)
  610.       (insert (format (concat nnfolder-article-marker "%d   %s\n")
  611.               (cdr group-art) (current-time-string))))))
  612.  
  613. (defun nnfolder-active-number (group)
  614.   ;; Find the next article number in GROUP.
  615.   (let ((active (cadr (assoc group nnfolder-group-alist))))
  616.     (if active
  617.     (setcdr active (1+ (cdr active)))
  618.       ;; This group is new, so we create a new entry for it.
  619.       ;; This might be a bit naughty... creating groups on the drop of
  620.       ;; a hat, but I don't know...
  621.       (push (list group (setq active (cons 1 1)))
  622.         nnfolder-group-alist))
  623.     (cdr active)))
  624.  
  625. (defun nnfolder-possibly-change-folder (group)
  626.   (let ((inf (assoc group nnfolder-buffer-alist)))
  627.     (if (and inf
  628.          (gnus-buffer-live-p (cadr inf)))
  629.     (set-buffer (cadr inf))
  630.       (when inf
  631.     (setq nnfolder-buffer-alist (delq inf nnfolder-buffer-alist)))
  632.       (when nnfolder-group-alist
  633.     (nnmail-save-active nnfolder-group-alist nnfolder-active-file))
  634.       (push (list group (nnfolder-read-folder group))
  635.         nnfolder-buffer-alist))))
  636.  
  637. ;; This method has a problem if you've accidentally let the active list get
  638. ;; out of sync with the files.  This could happen, say, if you've
  639. ;; accidentally gotten new mail with something other than Gnus (but why
  640. ;; would _that_ ever happen? :-).  In that case, we will be in the middle of
  641. ;; processing the file, ready to add new X-Gnus article number markers, and
  642. ;; we'll run across a message with no ID yet - the active list _may_not_ be
  643. ;; ready for us yet.
  644.  
  645. ;; To handle this, I'm modifying this routine to maintain the maximum ID seen
  646. ;; so far, and when we hit a message with no ID, we will _manually_ scan the
  647. ;; rest of the message looking for any more, possibly higher IDs.  We'll
  648. ;; assume the maximum that we find is the highest active.  Note that this
  649. ;; shouldn't cost us much extra time at all, but will be a lot less
  650. ;; vulnerable to glitches between the mbox and the active file.
  651.  
  652. (defun nnfolder-read-folder (group)
  653.   (let* ((file (nnfolder-group-pathname group))
  654.      (buffer (set-buffer (nnheader-find-file-noselect file))))
  655.     (if (equal (cadr (assoc group nnfolder-scantime-alist))
  656.            (nth 5 (file-attributes file)))
  657.     ;; This looks up-to-date, so we don't do any scanning.
  658.     buffer
  659.       ;; Parse the damn thing.
  660.       (save-excursion
  661.     (nnmail-activate 'nnfolder)
  662.     ;; Read in the file.
  663.     (let ((delim (concat "^" message-unix-mail-delimiter))
  664.           (marker (concat "\n" nnfolder-article-marker))
  665.           (number "[0-9]+")
  666.           (active (or (cadr (assoc group nnfolder-group-alist))
  667.               (cons 1 0)))
  668.           (scantime (assoc group nnfolder-scantime-alist))
  669.           (minid (lsh -1 -1))
  670.           maxid start end newscantime
  671.           buffer-read-only)
  672.       (buffer-disable-undo (current-buffer))
  673.       (setq maxid (cdr active))
  674.       (goto-char (point-min))
  675.  
  676.       ;; Anytime the active number is 1 or 0, it is suspect.  In that
  677.       ;; case, search the file manually to find the active number.  Or,
  678.       ;; of course, if we're being paranoid.  (This would also be the
  679.       ;; place to build other lists from the header markers, such as
  680.       ;; expunge lists, etc., if we ever desired to abandon the active
  681.       ;; file entirely for mboxes.)
  682.       (when (or nnfolder-ignore-active-file
  683.             (< maxid 2))
  684.         (while (and (search-forward marker nil t)
  685.             (re-search-forward number nil t))
  686.           (let ((newnum (string-to-number (match-string 0))))
  687.         (setq maxid (max maxid newnum))
  688.         (setq minid (min minid newnum))))
  689.         (setcar active (max 1 (min minid maxid)))
  690.         (setcdr active (max maxid (cdr active)))
  691.         (goto-char (point-min)))
  692.  
  693.       ;; As long as we trust that the user will only insert unmarked mail
  694.       ;; at the end, go to the end and search backwards for the last
  695.       ;; marker.  Find the start of that message, and begin to search for
  696.       ;; unmarked messages from there.
  697.       (when (not (or nnfolder-distrust-mbox
  698.              (< maxid 2)))
  699.         (goto-char (point-max))
  700.         (unless (re-search-backward marker nil t)
  701.           (goto-char (point-min)))
  702.         (when (nnmail-search-unix-mail-delim)
  703.           (goto-char (point-min))))
  704.  
  705.       ;; Keep track of the active number on our own, and insert it back
  706.       ;; into the active list when we're done.  Also, prime the pump to
  707.       ;; cut down on the number of searches we do.
  708.       (unless (nnmail-search-unix-mail-delim)
  709.         (goto-char (point-max)))
  710.       (setq end (point-marker))
  711.       (while (not (= end (point-max)))
  712.         (setq start (marker-position end))
  713.         (goto-char end)
  714.         ;; There may be more than one "From " line, so we skip past
  715.         ;; them.
  716.         (while (looking-at delim)
  717.           (forward-line 1))
  718.         (set-marker end (if (nnmail-search-unix-mail-delim)
  719.                 (point)
  720.                   (point-max)))
  721.         (goto-char start)
  722.         (when (not (search-forward marker end t))
  723.           (narrow-to-region start end)
  724.           (nnmail-insert-lines)
  725.           (nnfolder-insert-newsgroup-line
  726.            (cons nil (nnfolder-active-number nnfolder-current-group)))
  727.           (widen)))
  728.  
  729.       (set-marker end nil)
  730.       ;; Make absolutely sure that the active list reflects reality!
  731.       (nnmail-save-active nnfolder-group-alist nnfolder-active-file)
  732.       ;; Set the scantime for this group.
  733.       (setq newscantime (visited-file-modtime))
  734.       (if scantime
  735.           (setcdr scantime (list newscantime))
  736.         (push (list nnfolder-current-group newscantime)
  737.           nnfolder-scantime-alist))
  738.       (current-buffer))))))
  739.  
  740. ;;;###autoload
  741. (defun nnfolder-generate-active-file ()
  742.   "Look for mbox folders in the nnfolder directory and make them into groups."
  743.   (interactive)
  744.   (nnmail-activate 'nnfolder)
  745.   (let ((files (directory-files nnfolder-directory))
  746.         file)
  747.     (while (setq file (pop files))
  748.       (when (and (not (backup-file-name-p file))
  749.                  (message-mail-file-mbox-p
  750.           (nnheader-concat nnfolder-directory file)))
  751.         (let ((oldgroup (assoc file nnfolder-group-alist)))
  752.           (if oldgroup
  753.               (nnheader-message 5 "Refreshing group %s..." file)
  754.             (nnheader-message 5 "Adding group %s..." file))
  755.       (if oldgroup
  756.           (setq nnfolder-group-alist
  757.             (delq oldgroup (copy-sequence nnfolder-group-alist))))
  758.           (push (list file (cons 1 0)) nnfolder-group-alist)
  759.           (nnfolder-possibly-change-folder file)
  760.           (nnfolder-possibly-change-group file)
  761.           (nnfolder-close-group file))))
  762.     (message "")))
  763.  
  764. (defun nnfolder-group-pathname (group)
  765.   "Make pathname for GROUP."
  766.   (setq group (gnus-encode-coding-string group nnmail-pathname-coding-system))
  767.   (let ((dir (file-name-as-directory (expand-file-name nnfolder-directory))))
  768.     ;; If this file exists, we use it directly.
  769.     (if (or nnmail-use-long-file-names
  770.         (file-exists-p (concat dir group)))
  771.     (concat dir group)
  772.       ;; If not, we translate dots into slashes.
  773.       (concat dir (nnheader-replace-chars-in-string group ?. ?/)))))
  774.  
  775. (defun nnfolder-save-buffer ()
  776.   "Save the buffer."
  777.   (when (buffer-modified-p)
  778.     (run-hooks 'nnfolder-save-buffer-hook)
  779.     (gnus-make-directory (file-name-directory (buffer-file-name)))
  780.     (save-buffer)))
  781.  
  782. (provide 'nnfolder)
  783.  
  784. ;;; nnfolder.el ends here
  785.